Stata二維圖的坐標軸選擇

在Stata中，我們經常使用graph twoway命令繪制散點圖、折線圖、條形圖等二維圖。如果我們在繪圖時，需要使用多個坐標軸，這時應該怎么辦呢？？→_→這時就需要用到坐標軸的選項（axis_choice_options）啦！

該選項的基本語法如下：

yaxis(# [#...]), 1≤ # ≤ 9

xaxis(# [#...]), 1≤ # ≤ 9

默認（缺?。┣闆r下，Stata指定一個縱坐標軸和一個橫坐標軸，即yaxis(1)和xaxis(1)。Stata最多允許在橫縱兩個方向各設置9個坐標軸。例如：yaxis(1 2)，此時，縱軸的選擇默認為先左后右，即第一個縱軸在圖形左側，第二個縱軸在圖形右側；xaxis(1 2)，此時，橫軸的選擇默認為先下后上，即第一個橫軸在圖形下側，第二個橫軸在圖形上側；當設置的縱坐標軸（橫坐標軸）不少于3個時，坐標軸會擺放在二維圖的左側（下側），我們也可以通過命令來改變坐標軸的位置。

另外，為了使繪制的圖形更美觀，我們還可以通過繪圖的其它選項來設置指定坐標軸的標題、標簽、刻度和取值范圍，更改圖形或文字的位置、顏色、形狀、大小等。更多關于坐標軸的詳盡用法，請讀者使用Stata中的help文件來進一步學習（help axis_choice_options）。

接下來，我們通過構造一個簡單的數據集來介紹這一選項的使用方法。在繪圖之前，我們先構造一個數據集，生成繪圖所用的變量。

clear

set obs 55

set seed 123456789

gen time = _n

format time %td//日數據

gen week = week(time)//周標識

gen AR = ln(1+runiform())//超額收益率（日）

sort time

gen CAR = sum(AR)//累計超額收益率（日）

bysort week: egen meanAR = mean(AR)//平均超額收益率（周）

gen meanp_AR = meanAR/meanAR[_n-1] - 1//平均超額收益率變動率（周）

首先，我們使用單個y軸生成AR和CAR的折線圖。當只有1個y軸時，選項yaxis(1)可以省略，x軸同理。

twoway (line CAR time, lwidth(medthick)) (line AR time, lwidth(medthick))//使用一個y軸 

我們發現，當AR和CAR 使用同一y軸時，由于AR的取值范圍遠小于CAR，因此AR的變化在圖中并不明顯。

接下來，我們使用選項yaxis(n)設置雙y軸，生成AR和CAR的折線圖。其中，yaxis(1)指AR變量使用第一個y軸，yaxis(2)指CAR變量使用第二個y軸，第一個坐標軸選項yaxis(1)可以省略[l1] ，Stata最多允許在同一方向設置9個坐標軸。

twoway (line AR time,yaxis(1) lcolor(ebblue)) (line CAR time,yaxis(2) lcolor(cranberry))//雙y軸

此時，我們能明顯看出AR和CAR的變化趨勢。AR是日超額收益率，變化幅度較大；CAR是累計超額收益率，呈上升趨勢。

我們可以使用yaxis(n)和xaxis(n)選項設置2個y軸和2個x軸，生成AR的散點圖、CAR的折線圖和meanAR的條形圖。此時，由于變量取值范圍不同，AR和meanAR可以使用第一個y軸（0-0.8），CAR使用第二個y軸（0-25）；由于時間單位的不同，AR和CAR可以使用第一個x軸（日），meanAR使用第二個x軸（周）。為了輸出結果美觀，我們使用對圖形的顏色、寬度、大小等進行了調整，這些調整可以通過命令選項寫出，也可以直接在生成的圖形中修改。

twoway (bar meanAR week, xaxis(1) yaxis(1) color(ltblue) barw(0.6) xlabel(1(1)8)) (scatter AR time, c(l) ytitle(AR) xaxis(2) yaxis(1) mcolor(teal) msize(small) lcolor(teal)) (line CAR time, xaxis(2) yaxis(2) color(teal) lwidth(medthick))//雙x軸雙y軸

生成AR和CAR的折線圖，meanp_AR的條形圖。此時，由于變量取值范圍各不相同，AR, CAR和meanp_AR需要分別使用一個y軸；由于時間單位的不同，meanp_AR使用第一個x軸（周），CAR和AR使用第二個x軸（日）

twoway (bar meanp_AR week, xaxis(1) yaxis(1) barw(0.5) color(ltblue) xlabel(1(1)8, axis(1))) (line AR time, xaxis(2) yaxis(2) lcolor(teal)) (line CAR time,xaxis(2) yaxis(3) lcolor(teal)) //雙x軸三y軸

此時，我們發現，在Stata繪圖中，當設置的縱坐標軸（橫坐標軸）不少于3個時，縱坐標軸（橫坐標軸）會堆積在圖形左側（下側）。如果小伙伴們想要自行選擇坐標軸出現的位置，可以使用選項yscale(alt)或xscale(alt)，將指定的坐標軸移到另一側。

例如，我們希望把條形圖的縱軸移到右側顯示，使圖形更加美觀，我們可以使用yscale(alt)選項實現這一操作，命令如下：

twoway (bar meanp_AR week,xaxis(1) yaxis(1) yscale(alt) barw(0.5) color(ltblue) xlabel(1(1)8, axis(1))) (line AR time, xaxis(2) yaxis(2) lcolor(teal)) (line CAR time,xaxis(2) yaxis(3) lcolor(teal))  

此時，我們使用yscale(alt)選項將條形圖的縱軸移到右側顯示，并使用yline(0)選項為條形圖增加了一條y=0的水平參考線，增加了圖形的可讀性。